第1回キャッシュドロワを制御してみよう

パソコンとキャッシュドロワを接続インターフェースには通常3種類あります。

・レジプリンタなどに搭載されているＤＫＤ(Drawer Kick Driver)インターフェース
・RS232Cポートを利用したシリアルインターフェース
・USBポートを利用したシリアルインターフェース（USB<->RS232C変換）

このような接続インターフェースがありますが、最終的にはキャッシュドロワの内部にあるソレノイドを駆動することによってトレイを開くことになります。

※ソレノイドとは、トレイのロックをはずす電磁石のことです。この電磁石の電流を流すとドロワ内部のフックが外れトレイがドロワ内から出てきます。

今回は、現在主流になりつつあるUSBポートを搭載したキャッシュドロワの制御を行います。USBポートはUSBハブを利用することにより多くの機器を接続することが可能になりますがそれに伴って注意点もいくつか存在します。詳細は「USB接続機器についての情報」をご覧ください。

さて、キャッシュドロワをパソコンに接続してみます。今回使用するDWS48MRS-2/USB本体の背面を見てもUSBポートは存在しません。これはDWS48MRS-2/USB自身がDWS48MRS-2とRS232-USB I/Fコンバータ USB232-00のセット製品であるからです。

まず、キャッシュドロワの電源を投入していない状態で以下の手順を行います。このときパソコンの電源を投入しておいても問題はありません。

※USBコネクタにはシリーズA、シリーズB及びシリーズ・ミニBが存在します。通常は以下のような利用目的で使用します。

DWS48MRS-2はUSBインターフェース（USB232-00）を通してシリアル通信を行うことでトレイを開くことができます。以下が通信条件です。

制御プログラムを作成する場合の注意点がDWS48MRS-2取扱説明書の9ページと10ページに記載されています。必ずこの注意事項を読んだ上で作成してください。

今回は以下の環境を使ってプログラムを作成していきます。

注意：Microsoft Visual Studio .NET 若しくは .NET Frameworkがインストールされている環境では正常な開発及び実行ができない場合があります。Microsoft Visual Studio .NETを使用される場合は、今回のサンプルをVisual Basic .NETに置き換えてください。一部言語仕様が異なりますので注意して置き換えてください。

Windowsでパソコンのシリアル通信ポートを使ったプログラムを作成する際、汎用に使えるカスタムコントロールが用意されています。それがコミュニケーションコントロール（MSComm)です。このOCXを使えばVisual BasicでフォームにMSCommコントロールを貼り付けるだけで簡単にシリアルポートへの送受信プログラムを作ることができます。
それではVisualBasic6.0を起動してみましょう。
起動後、ツールボックスに下のアイコンが存在する人はすでにMSCommを使用したことがある人です。

このアイコンが存在しない場合は次の手順で追加してください。

新しいプロジェクト作成で起動すれば自動的にフォーム編集Windowが開きます。開かない場合にはプロジェクトエクスプローラ内のフォームをダブルクリックして開きます。その後、ツールボックスのMSCommのアイコンをクリックしてフォーム上に貼り付けます。このコンポーネントは実行時に表示されませんので適当な位置に貼り付けてください。

ここで話の流れをスムーズにするために貼り付けたMSCommコンポーネントの名前を変更しておきます。
貼り付けた直後はオブジェクト名がMSComm1になってますので、これをbox_commに変更しておきます。

次に、ボタンコントロールを貼り付けます。すでにキャッシュドロワが接続されているなら下記のプログラムを記述することでキャッシュドロワを開くことができます。

Private Sub Command1_Click  ()
Dim DataOutput(0) as Byte
Dim CountOutput as Integer
	Command1.Enabled = False
	box_comm.CommPort = 1	' キャッシュドロワの接続されてるポート番号
	box_comm.Settings = "300,n,8,1"
	box_comm.Handshaking = comNone
	box_comm.PortOpen = True
	DataOutput(0) = 0
	For CountOutput = 1 to 2
		box_comm.Output = DataOutput()
	Next
	Do
		DoEvents	' 送信確認中に他のイベントを処理できるようにする
	Loop Until box_comm.OutBufferCount = 0
	box_comm.PortOpen = false
	Command1.Enabled = true
End Sub

この状態では汎用性が無いので、以下の汎用的に使えるコードを掲載しておきます。

Private Function CommSet_(ary() As String)
On Error GoTo CommSet_Err
Dim comm As MSComm
    Set comm = box_comm
    comm.CommPort = ary(0)
    comm.Settings = ary(1) & "," & ary(2) & "," & ary(3) & "," & ary(4)
    comm.Handshaking = comNone
    CommSet_ = True
CommSet_Exit:
    Exit Function
CommSet_Err:
    CommSet_ = False
    Resume CommSet_Exit
End Function

Public Function CommSet(data As String)
Dim ary() As String
    ary = Split(data, ",")
    CommSet = CommSet_(ary)
End Function

Public Sub BoxOpen()
Dim OutputData(0) As Byte
Dim OutputCount As Integer

    box_comm.PortOpen = True
    OutputData(0) = 0
    For OutputCount = 1 To 2
        box_comm.Output = OutputData
    Next
    Do
        DoEvents
    Loop Until box_comm.OutBufferCount = 0
    box_comm.PortOpen = False
End Sub

Private Sub Form_Load()
    CommSet "1,300,n,8,1"
End Sub

Private Sub Command1_Click()
    Command1.Enabled = False
    BoxOpen
    Command1.Enabled = True
End Sub

尚、以下のメソッドは他のフォームからも呼び出すことが可能ですので、このフォームをプロジェクトに追加するだけで使用することができます。

今回作成したVisual Basicのプロジェクトファイルと実行モジュールを公開しています。
下記のリンクからダウンロードしてください。

パソコンレジを作ってみよう！

第1回 キャッシュドロワを制御してみよう

第1回キャッシュドロワを制御してみよう